%%% Copyright (c) 2019, Sunet.
%%% See LICENSE for licensing information.

%% A client spawns an Erlang port running a proxy app, i.e. the
%% 'remote' program from p11-kit.

%% Receive p11 requests from p11p_server, forward them to the proxy app,
%% wait for a reply. If a reply is received within a timeout period,
%% proxy the reply to the requesting p11p_server. If the request
%% times out, inform the manager (our parent).

-module(p11p_client).
-behaviour(gen_server).

%% API.
-export([start_link/6]).
-export([request/2, stop/2]).

-include("p11p_rpc.hrl").

%% Genserver callbacks.
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2,
         code_change/3]).

%% Records and types.
-record(state, {
	  token :: string(),			% Token name.
	  timeout :: non_neg_integer(),

	  port :: port(),
	  replyto :: pid() | undefined,
	  timer :: reference() | undefined,
	  msg :: p11rpc:msg() | undefined,
	  recv_count = 0 :: non_neg_integer(),
	  send_count = 0 :: non_neg_integer()
	 }).

%% API.
-spec start_link(atom(), string(), pid(), string(), list(), non_neg_integer()) ->
			{ok, pid()} | {error, term()}.
start_link(ServName, TokName, Server, ModPath, ModEnv, Timeout) ->
    lager:info("~p: starting p11p_client for ~s", [self(), TokName]),
    gen_server:start_link({local, ServName}, ?MODULE,
			  [TokName, Server, ModPath, ModEnv, Timeout], []).

-spec request(pid(), p11rpc_msg()) -> {ok, non_neg_integer()}.
request(Client, Request) ->
    gen_server:call(Client, {request, Request}).

%% Use stop/1 instead of gen_server:stop/1 if you're uncertain whether
%% we (Pid) are alive or not. An example of when that can happen is
%% when the manager receives a server_event about a lost p11 app. If
%% the server process terminated on request from us because we timed
%% out on an rpc call, chances are that we have already terminated by
%% the time the manager acts on the information about the lost app.
stop(Pid, Reason) ->
    gen_server:cast(Pid, {stop, Reason}).

%% Genserver callbacks.
init([TokName, Server, ModPath, ModEnv, Timeout]) ->
    ProxyAppBinPath = p11p_config:proxyapp_bin_path(),
    Port = open_port({spawn_executable, ProxyAppBinPath},
		     [stream,
		      exit_status,
		      {env, ModEnv},
		      {args, [ModPath, "-v"]}	% FIXME: Remove -v
		     ]),
    true = is_port(Port),
    lager:debug("~p: ~s: new proxy app port: ~p", [self(), ProxyAppBinPath, Port]),
    lager:debug("~p: ~s: module: ~s, env: ~p", [self(), ProxyAppBinPath, ModPath, ModEnv]),
    {ok, #state{port = Port, token = TokName, replyto = Server, timeout = Timeout}}.

handle_call({request, Request}, {FromPid, _Tag},
	    #state{port = Port, send_count = Sent} = S) ->
    %%lager:debug("~p: sending request from ~p to prxoy app ~p", [self(), FromPid, Port]),
    D = p11p_rpc:serialise(Request),
    Buf = case Sent of
	      0 -> <<?RPC_VERSION:8, D/binary>>;
	      _ -> D
	  end,
    {ok, _} = do_send(Port, Buf),
    {reply, {ok, sizeBuf}, S#state{replyto = FromPid,
				   timer = start_timer(S#state.timeout, Port),
				   send_count = Sent + 1}};

handle_call(Call, _From, State) ->
    lager:debug("~p: Unhandled call: ~p~n", [self(), Call]),
    {reply, unhandled, State}.

handle_cast({stop, Reason}, State) ->
    {stop, Reason, State};

handle_cast(Cast, State) ->
    lager:debug("~p: unhandled cast: ~p~n", [self(), Cast]),
    {noreply, State}.

%% Receiving the very first response from proxy app since it was started.
handle_info({Port, {data, Data}}, State)
  when Port == State#state.port, State#state.msg == undefined ->
    case hd(Data) of		% First octet is RPC protocol version.
	?RPC_VERSION ->
	    {noreply, handle_token_data(State, p11p_rpc:new(), tl(Data))};
	BadVersion ->
	    lager:info("~p: ~p: invalid RPC version: ~p", [self(), Port,
							   BadVersion]),
	    {noreply, State}
    end;

%% Receiving more data from proxy app.
handle_info({Port, {data, Data}}, #state{msg = Msg} = State)
  when Port == State#state.port ->
    {noreply, handle_token_data(State, Msg, Data)};

%% Proxy app timed out.
handle_info({timeout, Timer, Port}, S = #state{token = Tok})
  when Port == S#state.port, Timer == S#state.timer ->
    lager:info("~p: rpc request for ~s timed out, exiting", [self(), Tok]),
    p11p_manager:client_event(timeout, Tok),
    State = S#state{timer = undefined},
    {stop, normal, State};

handle_info(Info, State) ->
    lager:debug("~p: Unhandled info: ~p~n", [self(), Info]),
    {noreply, State}.

terminate(Reason, #state{port = Port}) ->
    lager:debug("~p: client terminating with reason ~p", [self(), Reason]),
    port_close(Port),
    ok.

code_change(_OldVersion, State, _Extra) ->
    {ok, State}.

%% Private
do_send(Port, Buf) ->
    Rand = rand:uniform(100), %% + 10,
    if
	Rand =< 10 ->
    	    lager:debug("~p: faking unresponsive token (~p) by not sending",
			[self(), Port]);
    	true ->
	    lager:debug("~p: sending ~B octets to token", [self(), size(Buf)]),
    	    true = port_command(Port, Buf)
    end,
    {ok, size(Buf)}.

handle_token_data(#state{replyto = Pid, timer = Timer, recv_count = Recv} = S,
		   MsgIn, DataIn) ->
    case p11p_rpc:parse(MsgIn, list_to_binary(DataIn)) of
	{needmore, Msg} ->
	    S#state{msg = Msg};
	{done, Msg} ->
	    cancel_timer(Timer),
	    lager:debug("~p: <- ~s", [self(), p11p_rpc:dump(Msg)]),
	    {ok, _BytesSent} = p11p_server:reply(Pid, Msg),
	    %% Saving potential data not consumed by parse/2 in new message.
	    S#state{msg = p11p_rpc:new(Msg#p11rpc_msg.buffer),
		    recv_count = Recv + 1}
    end.

start_timer(Timeout, Port) ->
    %%lager:debug("~p: starting timer", [self()]),
    erlang:start_timer(Timeout, self(), Port).

cancel_timer(Timer) ->
    %%lager:debug("~p: canceling timer", [self()]),
    erlang:cancel_timer(Timer, [{async, true}, {info, false}]).